Pedido script

SET_EVENT "<&SCRIPTEVENT_CHAT&>" "<&SYSTEM_CURRENTFILE&>" RecieveChat
DEFINE_GLOBAL ARRAYLIST playerlist 0
DEFINE_GLOBAL ARRAYLIST foelist 0
DEFINE_GLOBAL ARRAYLIST npclist 0
DEFINE_GLOBAL ARRAYLIST luckychestlist 0
DEFINE_GLOBAL DOUBLE XCOR = 0
DEFINE_GLOBAL STRING SENDERNAME
DEFINE_GLOBAL INT TREASURE 1021822
DEFINE_GLOBAL INT RADIO 600
DEFINE_GLOBAL INT LIMIT 15

DO
SLEEP 1000
LOOP ONE == ONE
END_SCRIPT
//FUNCTION THAT JOINS THE BOT INTO THE EVENT TROUGH ".JOIN" BRUTE FORCING ITS WAY INTO THE EVENT FOR THE BOT'S LEVEL
FUNCTION RecieveChat
//IN ORDER FOR THE BOT TO KNOW WHEN TO JOIN, I CHOSE A MESSAGE THAT KEEPS CONSTANT FOR ALL EVENTS, I HAVE IN BOTH LANGUAGES CUZ MY SERVER IS BILINGUAL
DEFINE STRING Trigger "Registration opened for 3 minute(s)."
DEFINE STRING sender "XXXX Events"
DEFINE STRING Trigger2 "Registro abierto durante 3 minuto(s)."
DEFINE STRING sender2 "Eventos XXXX"
DEFINE INT C 0

IF (sender == SENDERNAME) || (sender2 == SENDERNAME)
IF (MESSAGE == Trigger) || (MESSAGE == Trigger2)
DEFINE INT MAX 5
FOR EVENTO 0 4 1
SLEEP 2000
SAY_TEXT "<&CHANNEL_ALL&>" ".join"
PRINT_TEXT "Joining to event..."
NPC_DIALOG "bypass -h TnSEventParticipation <&EVENTO&>"
NEXT
//THE SCRIPT SAVES THE X LOCATION SO THAT WHEN THE SERVER TELEPORTS THE BOT, THE BOT CAN DETERMINE WHAT TYPE OF EVENT IS AND START THE CORRECT SEQUENCE
XCOR = CHAR_X
LABEL START
IF ( CHAR_X != XCOR )
//IF THE AMOUNT OF TREASURE CHESTS ARROUND EXCEEDS 10, THE BOT WILL ASSUME IT'S A LUCKYCHEST EVENT, OHERWISE IT WOULD BE PVP BASED
CALL TREASURECOUNT C 0
IF C == ZERO
PRINT_TEXT "Event is a PvP based"
CALL PVP VOID 0
ELSE
PRINT_TEXT "Event is a Lucky Chest event"
CALL luckychest VOID 0
ENDIF
ELSE
SLEEP 1000
JUMP_TO_LABEL START
ENDIF
ENDIF
ENDIF
RETURN VOID
//THIS FUNCTION COUNTS THE TREASURE CHESTS ARROUND, NOTHING EXTRAORDINARY
FUNCTION TREASURECOUNT 0
npclist.CLEAR
luckychestlist.CLEAR
INCLUDE npc.l2c
GET_NPCS npclist
PRINT_TEXT "Getting npc list"
FOREACH A NPC npclist
IF TREASURE == npclist.A.ID
luckychestlist.PUSH npclist.A
PRINT_TEXT "Creating chest list..."
ENDIF
NEXTEACH
PRINT_TEXT "Counting chests arround..."
IF luckychestlist.LENGTH > LIMIT
RETURN ONE
ELSE
RETURN ZERO
ENDIF
RETURN VOID
//THIS FUNCTION CLASSIFIES THE PLAYERS IN THE NEIGHBORHOOD AS ENEMIES OR FRIENDS BASED ON HOW CLOSE THEY ARE
FUNCTION PVP 0
DEFINE INT distancia
DEFINE INT SSUID
//GETS THE UNIQUE ID OF S GRADE SOULSHOTS
INVEN_GET_ITEMID SSUID 1467
SLEEP 7000
playerlist.CLEAR
foelist.CLEAR
INCLUDE StdLib\player.l2c
PRINT_TEXT "Getting player list..."
GET_PLAYERS playerlist
//DEFINES ENEMIES
FOREACH A PLAYER playerlist
COMMAND "/target <&playerlist.A.NAME&>"
DISTANCE distancia CHAR_X CHAR_Y CHAR_Z TARGET_X TARGET_Y TARGET_Z
PRINT_TEXT "Calculating distance to target..."
IF distancia >= RADIO
foelist.PUSH playerlist.A
PRINT_TEXT "ENEMY: <&foelist.A.NAME&>"
ENDIF
NEXTEACH
SLEEP 2000
//TARGET AND ATTACKS EACH PLAYER IN FOELIST WHILE THE BOTS LOCATION IS STILL DIFFERENT FROM PREVIOUS LOCATION
WHILE ( CHAR_X != XCOR )
FOREACH A PLAYER foelist
SLEEP 500
TARGET_SELF
COMMAND "/target <&foelist.A.NAME&>"
//WHILE THE TARGET SEEMS ALIVE AND YOUR BOT IS NOT DEAD, IT'LL KEEP ATTACKING
WHILE ( TARGET_LOOKS_DEAD != ONE ) && ( CHAR_CUR_HP != ZERO )
MOVE_TO "<&TARGET_X&>" "<&TARGET_Y&>" "<&TARGET_Z&>"
//PRINT_TEXT "Moving towards target..."
USE_ITEM "<&SSUID&>"
ATTACK_TARGET
//PRINT_TEXT "Engaging in combat..."
IF CHAR_CUR_HP == ZERO
BREAK 2
ENDIF
WEND
NEXTEACH
WEND
RETURN VOID
//THIS FUNCTION BASICALLY TARGETS AND ATTACKS CHESTS AND SINCE ONE HIT IS ENOUGH, THE TARGET'S STATUS IS NOT CHECKED
FUNCTION luckychest 0
WHILE ( CHAR_X != XCOR )
TARGET_SELF
TARGET_NEAREST_ID "<&TREASURE&>"
MOVE_TO "<&TARGET_X&>" "<&TARGET_Y&>" "<&TARGET_Z&>"
PRINT_TEXT "Moving towards target..."
ATTACK_TARGET
PRINT_TEXT "Attacking Chest"
WEND
RETURN VOID